Evolution IRCWX

[Winz]

On ‎5‎/‎8‎/‎2019 at 4:14 AM, JOhnson said:

#welcome on
on *:Join:#:{
  if ($nick == $me) {
    halt
  }
  else {
    msg # Welcome $nick
    }
}

That code worked for me... 

For some reason Shannons didn't. However, when I wrote another on *:TEXT:*Testing 2 3:#: { /msg # reply } it worked right away.

Then I continued to disseminate Shannons code even down to just a * left, and mIRC still wouldn't reconize anything. So then, I re-typed it out and it worked. So I'm not sure if mIRC at times isn't recognizing the # as a channel at times or what. Even $chan wasn't working in Shannons original code.

Personally, I think it has to do with how mIRC is filling the # and $chan values with existing code, so I'm not sure what is going on...

Anyway, hope this info helps.

[err0r]

have you tried using on *:text:*kicks da bot*:#:{ }

[JOhnson]

Winz ... will you post anything you finds wrong

err0r haves you tested any codes in Evolution i.e Ghost Kicker ... that works fine in buzzen and SPCN but not in Evolution

Again thank you for all replies to this topic

[Winz]

err0r, yes, I copied and pasted her code from here to try it and slowly disseminated the code, changed the command to something else etc and it didn't work until I deleted the entire line and put it all back in again. Like I said, I think it had something to do with the #.

Johnson, I tested the ghost kicker, my msn weather, and other remote commands and some menu options. They all worked fine.

[JOhnson]

Well I also have tested the codes again and they still they don't work ... why do they work in two other chat networks Buzzen & SPCN which also use's IRCWX and the same server

(Johnson, I tested the ghost kicker, my msn weather, and other remote commands and some menu options. They all worked fine.)

I have spoken to one or two other people who use bots with the same codes that Buzzen & SPCN use and they are telling me the same ... the codes aren't working ... no welcome, not away ect ? so now I am confused which doesn't take a lot to do with me 

again as always thank you for the reply and the help

[Winz]

8 minutes ago, JOhnson said:

I have spoken to one or two other people who use bots with the same codes that Buzzen & SPCN use and they are telling me the same ... the codes aren't working ... no welcome, not away ect ? so now I am confused which doesn't take a lot to do with me 

Yeah thats odd bud... One thing I did notice, is that it looks like Evolution's server does not send the [style] font code from web chat... I don't know if Duke is using an updated version of IRCwx or what... I was using mIRC 7.52 as well.. So check mIRC version...

In any case, when I was testing Shannons on TEXT line nothing was being sent to server to reply anywhere on that line of code that was edited. It was only after I deleted/saved and re-entered the line did it work, so I don't know WTH lol

Sorry man!

[Shannons69]

2 minutes ago, Winz said:

One thing I did notice, is that it looks like Evolution's server does not send the [style] font code from web chat... I don't know if Duke is using an updated version of IRCwx or what... I was using mIRC 7.52 as well.. So check mIRC version...

That makes some sense to me Winz, keeping in mind I am not a coder...  As when a guest tried to use the weather addon - it worked sometimes - but for me with unicode nick and in web, it would not at all..

P.s. Thanks again for all of your effort into this, it is truly appreciated...  

[err0r]

The style code seems to be sending like it's supposed to.

raw socket return

sock.server: :err0r8703!1.13e3dae.6512bd43d9caa6e02c990b0a82652dca@EvoMember PRIVMSG %#IRCommunity :[style ff:Abadi MT Condensed Light;co:#000000;]test[/style]

There really should be no difference in the chat setup for evolution than buzzen or spcn. all code should work exactly the same. I have tested everything talked about and it has worked fine for me. If there are other specific snippets not working please post them and i will test them.

Join code seems to work fine

[Shannons69]

I completely agree that there should be no difference but it is not what I have found. My trouble is that I am not a coder. I take stuff that has been made for me and move from one script to another and have been doing that for years.

I run a copy of Fracture on ECN and my google snippit works there, in it. It is the same snippit I have used for years in several different scripts on SPCN.  I had converted Justice League to connect to EVO from SPCN. I have already successfully been able to use the first edition of Winz's weatheraddon on EVO in the script but when I try to update to current version that saves the location, it stops working. I have tried to get the google snippit to work in the Justice League conversion and it will not work. 

I thought, it has to be my fault and I downloaded the new Moschino script that you (err0r) thankfully provided for EVO and it will not work in it either. I had asked Red to make me a copy of Fracture for EVO and because of his time constraints, he offered to help me convert it from ECN to EVO. (Only copy of Fracture I have.)

I explained of my troubles and he used teamveiwer to test it in the Moschino script (I had just downloaded this past week.) As I know it is clean, he was unable to get it to work as well. He put my snippit into his copy of Fracture already working on EVO and it works. I am sure that if I get my copy of Fracture converted, it should work. 

My main concern though is that ANY and all scripts should work basically the same on EVO (If new and designed for EVO from the get go.) but am finding that not to be the case. For me and I am sure others like me, this can be frustrating when it really shouldn't be. I hope I have explained myself properly but if not, please let me know and I will clarify anything if need be. Below is a copy of the snippit in question at the moment  - Google.mrc - This is the exact same thing I am running on two different servers in two different types of scripts and it works.

As always, thank you for anyone's time and patience, that offers assistance to this, it actually does mean a lot to me...  

-----------------------------------------------------------------------------------------------------------------------------------------------------------------------------

;.oO{ Google v1.9 by HM2K }Oo. - www.hm2k.org

;Installation: Make sure google.mrc is in your $mircdir then type: /load -rs google.mrc

;Usage: /g or /google <string> or /gs or /googlesay <string> (There is also a popup menu)

;Google v1.9 - Changed the error message to be more in line with what google does now
;Google v1.8 - Revamped some of the code a little
;Google v1.7 - Resorted back to the simple method, fixed a few relaying bugs
;Google v1.6 - Changed the lookup method to a more complicated one (it means the script is more flexable), and added total results to the output, debug mode was added too.
;Google v1.5 - Added simple flood protection, and urlencoding.
;Google v1.4 - Completly changed most of the way the script works including the output.
;Google v1.3 - Original public release.

;Settings
alias -l google.ver return Google v1.9
alias -l google.server return www.google.com
alias -l google.prefix return * Google:

;Code
alias letme say http://letmegooglethatforyou.com/?q= $+ $urlencode($1-)

alias -l google.out return $google.relay($1-) $google.prefix
alias -l google.relay {
  var %out echo $color(info2) -gat
  if ($modespl) {
    if ($1) {
      if (($ifmatch != Status Window) && ($ifmatch != -)) {
        if ($left($1,1) != $chr(35)) { var %out msg $1 }
        elseif ($chan($1)) { var %out msg $1 }
      }
    }
    elseif (($nick) && ($nick != $me)) var %out notice $nick
  }
  return %out
}

alias g google $1-
alias gs googlesay $1-

alias google {
  if (!$1) { $google.out Usage: google (-<server>) <text> | halt }
  if ($left($1,1) == -) { var %server = $right($1,-1) }
  google.open $iif(%server,%server,$google.server) $google.encode($iif(%server,$2-,$1-))
}
alias googlesay {
  if (!$1) { $google.out Usage: google (-<server>) <text> | halt }
  if ($left($1,1) == -) { var %server = $right($1,-1) }
  if ($left($1,1) == @) { var %nick = $right($1,-1) }
  google.open $iif(%server,%server,$google.server) $google.encode($iif(%server,$2-,$1-)) $active %nick
}

#!google on
on *:text:*:*: {
  if ($strip($1) == `google) {
    if (!$2) { $google.out($iif($chan,$chan,$nick)) Usage: google <text> | return }
    if ($1 == !googleuk) { var %server = www.google.co.uk }
    if ($1 == !google2) { var %server = www2.google.com }
    if ($1 == !google3) { var %server = www3.google.com }
    google.open $iif(%server,%server,$google.server) $google.encode($2-) $iif($chan,$chan,$nick) $nick
    $repeatcheck(`google)
  }
}
#!google end

alias -l repeatcheck { ;v0.12 by HM2K - will disable the appropriate group if its flooded
  var %rep.lim = 3
  var %rep.t.lim = 25
  var %rep.t.expr = 10
  if (%rep.lockusr- [ $+ [ $nick ] ]) { echo $ifmatch | haltdef }
  inc $+(-u,%rep.t.lim,$chr(32),%,rep-,$nick,.,$len($strip($1-)),.,$hash($strip($1-),32)) 1
  if (%rep- [ $+ [ $nick ] $+ . $+ [ $len($strip($1-)) ] $+ . $+ [ $hash($strip($1-),32) ] ] == %rep.lim) {
    ;ignore -u60 $address($nick,5)
    if ($group($chr(35) $+ $1) == on) { .disable $chr(35) $+ $1 | .echo -gat $1 is $group($chr(35) $+ $1) due to a repeat flood from $iif($chan,$nick in $chan,$nick) $+ , to re-enable: /enable $chr(35) $+ $1 }
    .set $+(-u,%rep.t.expr,$chr(32),%,rep.lockusr-,$nick) 1
  }
}

alias -l google.encode {
  return $urlencode($strip($1-))
}

alias -l google.open { ;Usage: <server[:port]> <text> [nick/chan]
  if (!$1) { $google.out Usage: google.open <server[:port]> <text> [nick/chan] | halt }
  if ($sock($google.id($2))) { sockclose $google.id($2) }
  if ($1) { sockopen $google.id($2) $iif(: isin $1,$replace($1,:,$chr(32)),$1 80) }
  else { $google.out Usage: google.open <server[:port]> <text> [nick/chan] | halt }
  set % $+ $google.id($2) $1 $strip($2) $3
}

alias -l google.id { return google. $+ $md5($1) }

on *:sockopen:google.*: {
  if ($sockerr > 0) { return }
  sockwrite -tn $sockname HEAD /search?btnI=&q= $+ $gettok($(% $+ $sockname,2),2,32) HTTP/1.0
  sockwrite -tn $sockname $crlf
}
on *:sockread:google.*: {
  if ($sockerr > 0) { return }
  :i
  if ($sock($sockname) != $null) { sockread -f %y }
  if ($sockbr == 0) { return }

  if (Location: isin %y) {
    var %y $gettok(%y,2,32)
    if ($left(%y,1) == /) var %y $+(http://,$sock($sockname).addr,%y)
    sockmark $sockname %y
    halt
  }

  goto i
}
on *:sockclose:google.*: { 
  var %out $iif($sock($sockname).mark,$sock($sockname).mark,Google wasn't feeling lucky.) See: $+(http://,$sock($sockname).addr,/search?q=,$gettok($(% $+ $sockname,2),2,32))
  $google.out($iif($gettok($(% $+ $sockname,2),3,32),$ifmatch,)) %out
  unset $(% $+ $sockname,1)
}
menu status,menubar,channel,query {
  $google.ver
  .Google Search: { google $?="text?" }
  .Google Say: { googlesay $?="text?" }
  .!google trigger $group(#!google) : {
    if ($group(#!google) == off) { .enable #!google | google.out !google is enabled }
    else { .disable #!google | google.out !google is disabled }
  }
}

alias -l urlencode {
  var %t = $len($1-),%r = "",%c
  while (%t) {
    %c = $asc($right($1,%t))
    if (%c == 32) { %c = + }
    elseif ((%c <= 32) || (%c == 34) || (%c == 38) || (%c == 43) || (%c >= 127)) { %c = % $+ $base($ifmatch,10,16,2) }
    else { %c = $chr(%c) }
    %r = %r $+ %c
    dec %t
  }
  return %r
}
#google.sockdebug off
;debug mode for sockets v0.02 by HM2K
alias -l sockdebug {
  var %win @sockdebug
  if (!$window(%win)) { window -e %win }
  if ($1-) { aline %win $timestamp $1- }
}
alias -l sockopen {
  sockopen $1-
  sockdebug -> sockopen $1-
}
alias -l sockwrite {
  sockwrite $1-
  sockdebug > sockwrite $1-
}
alias -l sockread {
  sockread $($1-,1)
  sockdebug < sockread $sockname $($1-,2)
}
alias -l sockclose {
  sockclose $1-
  sockdebug <- sockclose $1-
}
#google.sockdebug end

;EOF
 

[err0r]

I think the issue is with the Evo version of Moschino. Somehow two aliases that control /msg were corrupted. I have updated the file on tg with the fix and you should get the latest one. https://tg007.net/file-1772