not sure what you mean "raw" but here is the whole kicker. btw the other one did not work.
; This profile scanner captures the minimal (but relevant) details of a user profile.
; There is still more profile information which could be captured, for those who want to extend this.
; Dabba
; [url=http://ghetto-fusion.com/moschino/]http://ghetto-fusion.com/moschino/[/url]
dialog profile_manager {
title Moschino[Buzzen] profile manager..
size -1 -1 199 200
option dbu
list 1, 0 1 77 181, size
box "Profile capture (right-click a nickname)", 2, 79 1 119 78
button "Ok", 4, 161 187 37 12, ok
text "Name:", 6, 83 11 20 8
text "", 7, 122 10 72 8
text "Age:", 8, 83 22 18 8
text "Marital status:", 9, 83 33 37 8
text "", 11, 122 22 72 8
text "", 12, 122 33 72 8
text "Location:", 13, 83 44 24 8
text "", 14, 122 44 72 8
text "Gender:", 15, 83 55 25 8
text "Email:", 16, 83 66 25 8
text "", 17, 122 55 72 8
text "", 18, 122 66 72 8
check "Scan profiles onjoin", 3, 79 80 58 10
check "Msg profiles", 19, 79 96 50 10
check "Echo profiles", 20, 79 88 50 10
check "Kick users under age:", 21, 79 111 63 10
edit "", 22, 142 109 28 10, center
check "Kick users with undisclosed name", 23, 79 127 99 10
check "Kick users with undisclosed age", 24, 79 119 87 10
check "Kick males", 25, 79 143 50 10
check "Kick females", 26, 79 151 50 10
box "", 5, -7 181 208 4
check "Kick users with undisclosed gender", 27, 79 135 97 10
check "Halt kick on owners/hosts", 28, 79 165 75 10
check "Ban users for 5 minutes", 29, 79 173 70 10
link "http://ghetto-fusion.com/moschino", 10, 2 189 87 8
}
on *:DIALOG:profile_manager:init:0:{
var %f = dll $+(", $Mircdirdlls\mdx.dll, ")
%f SetMircVersion $Version
%f MarkDialog $Dname
%f SetControlMDX $Dname 1 ListView report flatsb single grid rowselect > dlls\views.mdx
%f SetFont $Dname 1,2,3,4,5,6,7,8,9,10,11,12,14,13,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29 13 500 Tahoma
did -i $Dname 1 1 seticon list 0 icons\owner.ico
did -i $Dname 1 1 seticon list 0 icons\host.ico
did -i $Dname 1 1 seticon list 0 icons\profile.ico
did -i $Dname 1 1 seticon list 0 icons\staff.ico
did -i $dname 1 1 headerdims 180
did -i $dname 1 1 headertext Users - $Iif($Len($Active) > 23, $Left($Active, 21) $+ .., $Active)
if ($MainSettings(PROFILE, GET_PROFILE) == 1) did -c $Dname 3
if ($MainSettings(PROFILE, PROFILE_CHECK_ECHO) == 1) did -c $Dname 20
if ($MainSettings(PROFILE, PROFILE_CHECK_MSG) == 1) did -c $Dname 19
if ($MainSettings(PROFILE, KICK_USERS) == 1) {
did -c $Dname 21
did -e $Dname 22
}
did $Iif($MainSettings(PROFILE, GET_PROFILE) == 1, -e, -B) $Dname 20,19,21,23,24,27,25,26,22,28,29
if ($MainSettings(PROFILE, KICK_USERS) == 0) did -b $Dname 22
did -a $Dname 22 $MainSettings(PROFILE, UNDER_AGE)
if ($MainSettings(PROFILE, KICK_UNDISCLOSED_NAME) == 1) did -c $Dname 23
if ($MainSettings(PROFILE, KICK_UNDISCLOSED_AGE) == 1) did -c $Dname 24
if ($MainSettings(PROFILE, KICK_UNDISCLOSED_GENDER) == 1) did -c $Dname 27
if ($MainSettings(PROFILE, KICK_MALES) == 1) did -c $Dname 25
if ($MainSettings(PROFILE, KICK_FEMALES) == 1) did -c $Dname 26
if ($MainSettings(PROFILE, HALT_OPS) == 1) did -c $Dname 28
if ($MainSettings(PROFILE, BAN_USERS) == 1) did -c $Dname 29
if ($Nick($Active, 0)) List_Nicks
}
on *:DIALOG:profile_manager:sclick:*:{
var %f = dll $+(", $Mircdirdlls\popups.dll, "), %D = $Did
if (%D == 1) {
if ($Gettok($Did(1, 1), 1,32) == RCLICK) && ($Did($Dname, 1).seltext) {
tokenize 32 $Did(1).seltext
var %x = clipboard_options
%f New %x 5 5
%f SetStyle %x bordertext bordericon
%f AddItem %x end +d Nickname: $6
%f AddItem %x end +d Channel: $Active
%f AddItem %x end
%f AddItem %x end + Check $6 $+ 's profile $Cr Get_Profile $Hget(PROFILE_D, $6) $Active DIALOG_CHECK
popupHandle %x $mouse.dx $mouse.dy
}
}
elseif (%D == 3) {
var %Switch = $Iif($MainSettings(PROFILE, GET_PROFILE) == 1, -b, -e)
MainSettings PROFILE GET_PROFILE $Iif($MainSettings(PROFILE, GET_PROFILE) == 1, 0, 1)
did %Switch $Dname 20,19,21,23,24,27,25,26,22,28,29
}
elseif (%D == 19) {
if ($MainSettings(PROFILE, PROFILE_CHECK_MSG) == 1) {
MainSettings PROFILE PROFILE_CHECK_MSG 0
MainSettings PROFILE PROFILE_CHECK_ECHO 1
did -c $Dname 20
}
else {
MainSettings PROFILE PROFILE_CHECK_MSG 1
MainSettings PROFILE PROFILE_CHECK_ECHO 0
did -u $Dname 20
}
}
elseif (%D == 20) {
if ($MainSettings(PROFILE, PROFILE_CHECK_ECHO) == 1) {
MainSettings PROFILE PROFILE_CHECK_ECHO 0
MainSettings PROFILE PROFILE_CHECK_MSG 1
did -c $Dname 19
}
else {
MainSettings PROFILE PROFILE_CHECK_ECHO 1
MainSettings PROFILE PROFILE_CHECK_MSG 0
did -u $Dname 19
}
}
elseif (%D == 21) {
if ($MainSettings(PROFILE, KICK_USERS) == 1) {
MainSettings PROFILE KICK_USERS 0
did -b $Dname 22
}
else {
MainSettings PROFILE KICK_USERS 1
did -e $Dname 22
}
}
elseif (%D == 4) {
var %N = $Did(22)
if (%N < 16) || ($Len(%N) != 2) Printf -a * The under age must be a 2 digit number between more than or equal to 16.
else MainSettings PROFILE UNDER_AGE %N
}
elseif (%D == 23) MainSettings PROFILE KICK_UNDISCLOSED_NAME $Iif($MainSettings(PROFILE, KICK_UNDISCLOSED_NAME) == 1, 0, 1)
elseif (%D == 24) MainSettings PROFILE KICK_UNDISCLOSED_AGE $Iif($MainSettings(PROFILE, KICK_UNDISCLOSED_AGE) == 1, 0, 1)
elseif (%D == 27) MainSettings PROFILE KICK_UNDISCLOSED_GENDER $Iif($MainSettings(PROFILE, KICK_UNDISCLOSED_GENDER) == 1, 0, 1)
elseif (%D == 25) MainSettings PROFILE KICK_MALES $Iif($MainSettings(PROFILE, KICK_MALES) == 1, 0, 1)
elseif (%D == 26) MainSettings PROFILE KICK_FEMALES $Iif($MainSettings(PROFILE, KICK_FEMALES) == 1, 0, 1)
elseif (%D == 28) MainSettings PROFILE HALT_OPS $Iif($MainSettings(PROFILE, HALT_OPS) == 1, 0, 1)
elseif (%D == 29) MainSettings PROFILE BAN_USERS $Iif($MainSettings(PROFILE, BAN_USERS) == 1, 0, 1)
elseif (%D == 10) RUN $Did(10)
}
; Do _NOT_ remove or edit this line. The version checker uses it.
alias ProfileManager_Version return 1.1
alias List_Nicks {
var %x 1
while (%x <= $Nick($Active, 0)) {
var %Nick = $Nick($Active, %x), %Decoded = $Buzz.decode(%Nick), %Icon
hadd -m PROFILE_D %Decoded %Nick
if ($Left(%Nick, 1) == $Chr(39)) %Icon = 0 4
elseif (%Nick isowner $Active) %Icon = 0 1
elseif (%Nick isop $Active) %Icon = 0 2
else %Icon = 0 3
did -a profile_manager 1 %Icon %Decoded
inc %x
}
}
alias Get_Profile {
var %Nick = $$1, %Chan = $$2, %Sock = PROFILE.SCAN. $+ $Numb(10)
sockopen %Sock www.buzzen.com 80
sockmark %Sock %Nick %Chan $Iif($3, $3)
if ($3 == DIALOG_CHECK) && ($Dialog(profile_manager)) {
did -ra profile_manager 2 Profile capture: $Buzz.decode(%Nick)
}
}
alias Print_Type return $Iif($MainSettings(PROFILE, PROFILE_CHECK_ECHO) == 1, echo, msg)
alias Profile_Capture {
tokenize 32 $1-
$Iif($Print_Type == echo, Printf, msg) $3 * Profile for $2 $4-
}
alias MultiProfileCheck {
var %x 1, %Chan = $1, %Nicks = $2-, %Total = $Numtok(%Nicks, 32)
$Print_Type %Chan * Multi select nick profile check on: $Replace(%Nicks, $Chr(32), $+($Chr(44), $Chr(32))) $RBracks(%Total nick[s])
$Print_Type %Chan -
while (%x <= %Total) {
var %Nick = $Gettok(%Nicks, %x, 32)
Get_Profile %Nick %Chan
inc %x
}
}
on ^!*:JOIN:#: {
if (!$Is_Guest($Nick)) && ($MainSettings(PROFILE, GET_PROFILE) == 1) Get_Profile $Nick #
}
on *:sockopen:PROFILE.SCAN.*: {
if ($Sockerr) return
tokenize 32 $Sock($Sockname).mark
sockwrite -n $Sockname GET /members/usrProfile.php?phx= $+ $_Hex($1) HTTP/1.1 $+ $Crlf $+ $&
Accept: image/gif, image/x-xbitmap, image/jpeg, image/pjpeg, application/x-shockwave-flash, application/vnd.ms-excel, application/vnd.ms-powerpoint, application/msword, */* $+ $Crlf $+ $&
Accept-Language: EN-US $+ $CrLf $+ Accept-Encoding: gzip, deflate $+ $Crlf $+ $&
User-Agent: Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1) $+ $Crlf $+ $&
Host: www.buzzen.com $+ $CrLf $+ Connection: Keep-Alive $+ $Crlf $+ $&
Cookie: Cookie: lang=EN; $+ $Str($Crlf, 2)
}
on *:sockread:PROFILE.SCAN.*: {
if ($Sockerr > 0) return
var %Read, %Nick = $Gettok($Sock($Sockname).mark, 1, 32), %Chan = $Gettok($Sock($Sockname).mark, 2, 32)
sockread %Read
tokenize 32 %Read
if (*HTTP/1.1 302 Found* iswm %Read) halt
elseif (*<strong>Name* iswm %Read) {
sockread %Read
sockmark $Sockname $Sock($Sockname).mark $+ $Chr(32) $+ $Iif($Len(%Read) == 24, $SBracks(Name: Unset), $SBracks(Name: %Read))
if (*DIALOG_CHECK* iswm $Sock($Sockname).mark) && ($Dialog(profile_manager)) {
did -a profile_manager 7 $Iif($Len(%Read) == 24, Unset, %Read)
}
if ($MainSettings(PROFILE, KICK_UNDISCLOSED_NAME) == 1) && ($Len(%Read) == 24) {
.signal -n PROFILE_KICKER UNDISCLOSED_NAME %Nick %Chan
}
}
elseif (*<strong>Age* iswm %Read) {
sockread %Read
sockread %Read
sockmark $Sockname $Sock($Sockname).mark $+ $Chr(32) $+ $SBracks(Age: %Read)
if (*DIALOG_CHECK* iswm $Sock($Sockname).mark) && ($Dialog(profile_manager)) did -a profile_manager 11 %Read
.signal -n PROFILE_KICKER AGE %Nick %Chan %Read
}
elseif (*<strong>Marital Status* iswm %Read) {
sockread %Read
sockread %Read
sockmark $Sockname $Sock($Sockname).mark $+ $Chr(32) $+ $SBracks(Marital status: %Read)
if (*DIALOG_CHECK* iswm $Sock($Sockname).mark) && ($Dialog(profile_manager)) did -a profile_manager 12 %Read
}
elseif (*<strong>Location* iswm %Read) {
sockread %Read
sockmark $Sockname $Sock($Sockname).mark $+ $Chr(32) $+ $SBracks(Location: %Read)
if (*DIALOG_CHECK* iswm $Sock($Sockname).mark) && ($Dialog(profile_manager)) did -a profile_manager 14 %Read
}
elseif (*<strong>Gender* iswm %Read) {
sockread %Read
sockread %Read
sockmark $Sockname $Sock($Sockname).mark $+ $Chr(32) $+ $SBracks(Gender: %Read)
if (*DIALOG_CHECK* iswm $Sock($Sockname).mark) && ($Dialog(profile_manager)) did -a profile_manager 17 %Read
.signal -n PROFILE_KICKER GENDER %Nick %Chan %Read
}
elseif (*<strong>Email Address* iswm %Read) {
sockread %Read
sockmark $Sockname $Sock($Sockname).mark $+ $Chr(32) $+ $SBracks(Email: %Read)
if (*DIALOG_CHECK* iswm $Sock($Sockname).mark) && ($Dialog(profile_manager)) did -a profile_manager 18 %Read
else $Profile_Capture($Sockname $Sock($Sockname).mark)
sockclose $Sockname
return
}
}
; Profile kicker
on *:SIGNAL:PROFILE_KICKER:{
var %Type = $1, %Nick = $2, %Chan = $3, $&
%SendKick = sockwrite -n $C_Sock(%Chan) KICK %Chan %Nick, $&
%Ban
if (%Nick ison %Chan) {
if (%Nick isop %Chan) && ($MainSettings(PROFILE, HALT_OPS) == 1) return
%Ban = $Iif($MainSettings(PROFILE, BAN_USERS) == 1, $LF ACCESS %Chan ADD DENY *!* $+ $Ial(%Nick).addr) 5
if (%Type == AGE) {
if ($4 == Undisclosed) && ($MainSettings(PROFILE, KICK_UNDISCLOSED_AGE) == 1) {
access # add DENY *! $+ $$ial($nick $+ *,1).addr 5 | %SendKick :Your age is undisclosed. Please specify an age in your profile.
}
elseif ($4 < $MainSettings(PROFILE, UNDER_AGE)) && ($MainSettings(PROFILE, KICK_USERS) == 1) {
%SendKick :You are $4 years of age. Too young for this room.
}
}
elseif (%Type == UNDISCLOSED_NAME) {
%SendKick :What's your name? You have no name in your profile.
}
elseif (%Type == GENDER) {
if ($4 == Undisclosed) && ($MainSettings(PROFILE, KICK_UNDISCLOSED_GENDER) == 1) {
%SendKick :You have no gender in your profile. Please specify your sex and come back later.
}
elseif ($4 == Male) && ($MainSettings(PROFILE, KICK_MALES) == 1) %SendKick :No males allowed in this room.
elseif ($4 == Female) && ($MainSettings(PROFILE, KICK_FEMALES) == 1) %SendKick :No females allowed in this room.
}
}
}
menu status,channel {
-
Profile manager: Open_Dialog profile_manager
-
}
menu nicklist {
-
Profile
.View users buzzen profile on web: OpenProfile $$1
.-
.Multi-select profile(s) check: MultiProfileCheck # $1-
-
}
*Edit by X-Fusion - Just added some
tags so it wouldnt look so messy.
