; Simple theme
; Made by miceiken
; Use font "Courier New" with the size 7px
; ALT + V -> Font

; Helpers
alias thmnick {
  var %n = $1, %c = $2
  var %mi

  if (%n isop %c) { %mi = @ }
  if (%n isvoice %c) { %mi = + }
  if (%n ishop %c) { %mi = % }
  if (%mi) { %n = %mi $+ %n }

  var %l = $len(%n)
  var %c = $calc(18 - %l - 1)
  var %r = $+($str($chr(160), %c), $chr(32), %n)
  return %r
}

alias indent {
  return $+($str($chr(160), $calc(18 - $len($1))), $1)
}

alias urlc {
  var %line = $1-
  if ($regex(%line,/(\b(www.?\.|https?:\/\/|ftp:\/\/).)/i)) {
    var %x = 1 
    while (%x <= $numtok(%line,32)) { 
      if ($regex($gettok(%line,%x,32),/(\b(www.?\.|https?:\/\/|ftp:\/\/).)/i)) { 
        var %l2 = $+($chr(3), 12, $chr(31), $gettok(%line, %x, 32), $chr(31), $chr(3))
        %line = $puttok(%line,%l2,%x,32)
      } 
      inc %x 
    }
  }
  return %line
}


alias thmnickpm {
  var %n = $1,
  var %l = $len(%n)
  var %c = $calc(18 - %l - 1)
  var %r = $+($str($chr(160), %c), $chr(32), %n)
  return %r
}

; Command enhancer

alias me {
  haltdef
  !.describe $active $1-
  echo 6 -ti26 $active $chr(160) $+ $thmnick($me, $active) $1-
}

alias ctcp {
  haltdef
  !.ctcp $1 $2-
  echo 4 -ti26 $active $indent(CTCP) $+ : -> $1 $upper($2-)
}

; Events

on *:START: {
  .timestamp on
  .timestamp -ef HH:nn
}

on *:INPUT:#: {
  if ($left($1,1) === $readini(mirc.ini, text, commandchar)) && (!$ctrlenter) { return }
  haltdef
  .msg # $1-
  echo -ti26 # $thmnick($me, $chan) $+ : $urlc($1-)
  window -g1 $chan
}

on *:INPUT:?: {
  if ($left($1,1) === $readini(mirc.ini, text, commandchar)) && (!$ctrlenter) { return }
  haltdef
  .msg $active $1-
  echo -ti26 $active $thmnickpm($me) $+ : $urlc($1-)
}


on ^*:TEXT:*:*: {
  haltdef
  if ($chan) {
    echo -ti26 # $thmnick($nick, $chan) $+ : $urlc($1-)
    window -g1 $chan
  }
  else {
    echo -ti26 $nick $thmnickpm($nick) $+ : $urlc($1-)
    window -g1 $nick
  }
}

on ^*:QUIT: {
  haltdef
  var %i = 1
  while (%i <= $comchan($nick, 0)) {
    echo 2 -ti26 $comchan($nick, %i) $indent(Quit) $+ : $nick ( $+ $1- $+ )
    window -g3 $comchan($nick, %i)
    inc %i
  }
}

on ^*:NICK: {
  haltdef
  var %i = 1
  while (%i <= $comchan($newnick, 0)) {
    echo 3 -ti26 $comchan($newnick, %i) $indent(Nick) $+ : $nick -> $newnick
    window -g3 $comchan($newnick, %i)
    inc %i
  }
}

on ^*:JOIN:#: {
  haltdef
  if ($nick != $me) {
    echo 3 -ti26 # $indent(Join) $+ : $nick
    window -g3 $chan
  }
}

on ^*:PART:#: {
  haltdef
  if ($nick != $me) {
    echo 3 -ti26 # $indent(Part) $+ : $nick $iif($1, $+($chr(40), $1-, $chr(41)))
    window -g3 $chan
  }
}

on ^*:RAWMODE:#: {
  haltdef
  echo 3 -ti26 # $indent(Mode) $+ : $nick sets $1-
}

on ^*:TOPIC:#: {
  haltdef
  echo 3 -ti26 # $indent(Topic) $+ : $nick -> $urlc($chan($chan).topic)
  window -g3 $chan
}

on ^*:ACTION:*:#: {
  haltdef
  echo 6 -ti26 # $chr(160) $+ $thmnick($nick, $chan) $1-
  window -g1 $chan
}

on ^*:CTCPREPLY:*: {
  var %o = $1-
  if ($1 == PING) {
    %o = $asctime($2, mm:ss)
  }
  haltdef
  echo 4 -ti26 $iif($chan, $chan, $active) $indent(CTCP) $+ : <- $iif($nick, $nick, $chan) %o
}

on ^*:KICK:#: {
  haltdef
  echo 3 -ti26 $chan $indent(Kick) $+ : $nick kicked $knick $iif($1 != $knick, $+($chr(40), $1-, $chr(41)))
}

; Abnormal events 

raw 332:*: {
  haltdef
  echo 3 -ti26 $2 $indent(Topic) $+ : $urlc($3-)
  window -g3 $2
}

raw 333:*: {
  haltdef
  echo 3 -ti26 $2 $indent(Set by) $+ : $3 at $asctime($4, HH:nn:ss) the $asctime($4, dd/mm)
  window -g3 $2
}

ctcp *:*:*: {
  haltdef
  echo 4 -ti26 $iif($chan, $chan, $active) $indent(CTCP) $+ : <- $iif($nick, $nick, $chan) $1-
}

;Whois
/*
<- :zeus.dallas.tx.us.americhat.net 311 miceiken Fl00k woof staff.americhat.net * :woof
<- :zeus.dallas.tx.us.americhat.net 319 miceiken Fl00k :@#idlerpg @#solid #genscripts 
<- :zeus.dallas.tx.us.americhat.net 312 miceiken Fl00k zeus.dallas.tx.us.americhat.net :located on earth
<- :zeus.dallas.tx.us.americhat.net 307 miceiken Fl00k :has identified for this nick
<- :zeus.dallas.tx.us.americhat.net 313 miceiken Fl00k :is an IRC Operator - Services Administrator
<- :zeus.dallas.tx.us.americhat.net 275 miceiken Fl00k :is a Secure Connection (SSL)
<- :zeus.dallas.tx.us.americhat.net 317 miceiken Fl00k 38 1234918827 :seconds idle, signon time
<- :zeus.dallas.tx.us.americhat.net 318 miceiken Fl00k :End of /WHOIS list.
$1       $2    $3-


raw 307:*: {
  haltdef
  echo -ati26 $str($chr(160), 2) $+ $indent(NickServ Identified)
}

raw 311:*: {
  haltdef
  echo -ati26 $indent(<whois nick=" $+ $2 $+ ">) 
  echo -ati26 $str($chr(160), 2) $+ $indent(Ident) $+ : $+ $3 Mask: $+ $4 
}

raw 312:*: {
  haltdef
  echo -ati26 $str($chr(160), 2) $+ $indent(Server) $+ : Connected to $3 ($4-)
}

raw 313:*: {
  haltdef
  echo -ati26 $str($chr(160), 2) $+ $indent(Flags) $+ : $5-
}

raw 317:*: {
  haltdef
  echo -ati26 $str($chr(160), 2) $+ $indent(Idle) $+ : $duration($3) 
  echo -ati26 $str($chr(160), 2) $+ $indent(Signon) $+ : $asctime($4, HH:nn)
}

raw 319:*: {
  haltdef
  var %i = 1, %o, %h, %v, %r, %c, %n
  while (%i <= $numtok($3-, 32))
  {
    %n = $calc(%i + 2)
    %c = $gettok($3-, %n, 32)
    echo -ati26 $indent(Channels) $+ :
  }

  raw 318:*: {
    haltdef
    echo -ati26 $indent(</whois>)
  }
  */